home *** CD-ROM | disk | FTP | other *** search
/ SGI Developer Toolbox 6.1 / SGI Developer Toolbox 6.1 - Disc 4.iso / src / exampleCode / irix / scripts / rcs / Setrcsname < prev    next >
Encoding:
Text File  |  1994-08-02  |  4.7 KB  |  167 lines
  1. #! /bin/csh -f
  2. #
  3. # $Id: Setrcsname,v 1.5 93/12/16 14:48:11 carlson Exp $
  4. #
  5. # Setrcsname    Sets a name for a revision of every RCS file.
  6. #
  7. # Synopsis:
  8. #    Setrcsname -n <name> [-l] [file-list]
  9. #    Setrcsname -n <name>:<rev> [-m] [file-list]
  10. #    Setrcsname -N <name> [-l] [file-list]
  11. #    Setrcsname -N <name>:<rev> [-m] [file-list]
  12. #
  13. # Description:
  14. #    This script sets a symbolic name for a revison of an RCS file.
  15. #
  16. #    In the first form, if the -l is not provided, the symbolic
  17. #    name is deleted (if it exists).  Otherwise, the last revision
  18. #    has the last component removed and is used as the revision.
  19. #    If the symbolic name already exists for another revision, an
  20. #    error is printed by rcs.
  21. #
  22. #    In the second form, the specified revision is given the
  23. #    symbolic name.  If the symbolic name already exists for
  24. #    another revision, an error is printed by rcs.
  25. #
  26. #    The third form is identical to the first form except if the
  27. #    symbolic name already exists for another revision, it is
  28. #    overridden.
  29. #
  30. #    The fourth form is identical to the second form except it the
  31. #    symbolic name already exists for another revision, it is
  32. #    overridden.
  33. #
  34. # Parameters:
  35. #    -n <name>    Symbolic name to define.
  36. #    -N <name>    Symbolic name to define and override if it exists.
  37. #    -l        Use last revision of file to set symbolic name to.
  38. #    -m        Set symbolic name only if revision exists.
  39. #
  40. # Revision History:
  41. #    $Log:    Setrcsname,v $
  42. # Revision 1.5  93/12/16  14:48:11  carlson
  43. # Added the ability to provide an actual file list to perform the function
  44. #   to on the command line.
  45. # 
  46. # Revision 1.4  92/10/27  10:05:50  carlson
  47. # Put checking of options in an if statement that is dependent on whether
  48. #   there are any options.  This allowed the usage statement to be printed
  49. #   if no options or arguments are provided.
  50. # 
  51. # Revision 1.3  92/08/21  16:31:00  carlson
  52. # Added more output to when called with no parameters.
  53. # 
  54. # Revision 1.2  91/07/27  20:07:12  chris
  55. # Completely revamped this script.  Provide all kinds of ways to set
  56. #   a symbolic name to a bunch of RCS files.
  57. # 
  58. #---------------------------------------------------------------------------
  59.  
  60. set name = ""
  61. set last = 0
  62. set override = 0
  63. set modify = 0
  64.  
  65. if ( $#argv >= 1 ) then
  66.     set argv = `getopt lmn:N: $*`
  67.     while ( "$1" != "--" )
  68.         switch ( $1 )
  69.           case "-l":
  70.         set last = 1
  71.         shift
  72.         breaksw
  73.  
  74.           case "-m":
  75.         set modify = 1
  76.         shift
  77.         breaksw
  78.  
  79.           case "-n":
  80.         set name = $2
  81.         shift; shift
  82.         breaksw
  83.  
  84.           case "-N":
  85.         set name = $2
  86.         set override = 1
  87.         shift; shift
  88.         breaksw
  89.         endsw
  90.     end
  91.     shift
  92. endif
  93.  
  94. if ( "$name" == "" ) then
  95.     echo "Usage: Setrcsname -n <name> [-l] [file-list]"
  96.     echo "       Setrcsname -n <name>:<rev> [-m] [file-list]"
  97.     echo "       Setrcsname -N <name> [-l] [file-list]"
  98.     echo "       Setrcsname -N <name>:<rev> [-m] [file-list]"
  99.     echo " -n <name>   Symbolic name to define."
  100.     echo " -N <name>   Symbolic name to define and override if it exists."
  101.     echo " -l          Use last revision of file to set symbolic name to."
  102.     echo " -m          Set symbolic name only if revision exists."
  103.     echo " [file-list] Optional list of files to do."
  104.     exit
  105. endif
  106.  
  107. #----
  108. # rev = revision portion of name provided (everything after :)
  109. # name = name portion (everything before :)
  110. # Revc = revision preceded by colon
  111. #
  112. set rev = `echo $name | awk -F: '{ print $2 }'`
  113. set name = `echo $name | awk -F: '{ print $1 }'`
  114.  
  115. if ( "$rev" != "" ) then
  116.     set last = 0
  117.     set Revc = :$rev
  118. else
  119.     set modify = 0
  120.     set Revc = ""
  121. endif
  122.  
  123. #----
  124. # If no files were provided on the command line,
  125. # loop through each RCS file found.  If there is an RCS directory,
  126. # loop through the files ending in ",v" in it.  Otherwise, loop
  127. # through files in the current directory ending in ",v".
  128. #
  129. set rcsdir = ""
  130. if ( -d RCS ) set rcsdir = "RCS/"
  131.  
  132. if ( $#argv == 0 ) then
  133.     set fileList = `ls ${rcsdir}*,v` 
  134. else
  135.     set fileList = ( $argv )
  136. endif
  137.  
  138. foreach rcsfile ( $fileList )
  139.     set file = `basename $rcsfile ,v`
  140.  
  141.     #----
  142.     # If we are supposed to set the last revision, get the last
  143.     # revision and remove the last component.
  144.     #
  145.     # If we are only to set the symbolic name if the revision exists,
  146.     # check if the revision exists and skip if not there.
  147.     #
  148.     if ( $last ) then
  149.     set rev = `rlog $file | grep "^head:" | awk '{print $NF}'`
  150.     set Rev = `echo $rev | awk -F. '{for(i=1;i<NF-1;i++)printf "%s.",$i;print $i}'`
  151.     set Revc = :$Rev
  152.     else if ( $modify ) then
  153.     set x = `rlog $file | grep "^revision $rev"`
  154.     if ( "$x" == "" ) continue
  155.     endif
  156.  
  157.     if ( $override ) then
  158.     rcs -N${name}${Revc} $file
  159.     else
  160.     rcs -n${name}${Revc} $file
  161.     endif
  162. end
  163.  
  164. ### Local Variables:
  165. ### auto-fill-hook: nil
  166. ### End:
  167.